1. Skip to Menu
  2. Skip to Content
  3. Skip to Footer

Невозможно добавить документ в библиотеку Sharepoint

 

При попытке загрузить в библиотеку Sharepoint документ вы получаете 500-ую ошибку. Кроме того, на ISA 2006 сервере (или TMG 2010) в мониторинге можно увидеть ошибку:

12302 The server denied the specified Uniform Resource Locator (URL)

Это связано с тем, что ISA/TMG не может обработать расширенные символы в запросной части ссылки (той, что после значка ?). Для исправления этой досадной ситуации надо запустить на сервере следующий VBS скрипт:

----------------------------------------------- начало скрипта -------------------------------------------------

Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
Const SE_VPS_NAME = "CookieFilterDecodeUEncoding"
Const SE_VPS_VALUE = true
 
Sub SetValue()
 
   ' Create the root object.
   Dim root ' The FPCLib.FPC root object
   Set root = CreateObject("FPC.Root")
 
   'Declare the other objects that are needed.
   Dim array       ' An FPCArray object
   Dim VendorSets ' An FPCVendorParametersSets collection
   Dim VendorSet   ' An FPCVendorParametersSet object
 
   ' Get references to the array object
   ' and to the network rules collection.
   Set array = root.GetContainingArray
   Set VendorSets = array.VendorParametersSets
 
   On Error Resume Next
   Set VendorSet = VendorSets.Item( SE_VPS_GUID )
 
   If Err.Number <> 0 Then
       Err.Clear
 
       ' Add the item
       Set VendorSet = VendorSets.Add( SE_VPS_GUID )
       CheckError
       WScript.Echo "New VendorSet added... " & VendorSet.Name
 
   Else
       WScript.Echo "Existing VendorSet found... value- " & VendorSet.Value(SE_VPS_NAME)
   End If
 
   if VendorSet.Value(SE_VPS_NAME) <> SE_VPS_VALUE Then
 
       Err.Clear
       VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE
 
       If Err.Number <> 0 Then
           CheckError
       Else
           VendorSets.Save false, true
           CheckError
 
           If Err.Number = 0 Then
               WScript.Echo "Done with " & SE_VPS_NAME & ", saved!"
           End If
       End If
   Else
       WScript.Echo "Done with " & SE_VPS_NAME & ", no change!"
   End If
End Sub
 
Sub CheckError()
 
   If Err.Number <> 0 Then
       WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
       Err.Clear
   End If
 
End Sub
SetValue
 
----------------------------------------------- конец скрипта -------------------------------------------------
 

Оригинальная статья находится здесь:  http://support.microsoft.com/kb/940248/en-us

 

Добавить комментарий